Automatyczne wyciszanie podczas zamykania systemu

Z ThinkPad-Wiki

Przejdź do: nawigacja, szukaj
Właściciele R52, T43, T43p, X41 lub X41 Tablet mają, ze względu na zaprojektowany i zamontowany przez IBM mostek SATA-to-IDE, nie tylko problem ze znalezieniem niewielu aktualnych dysków twardych o odpowiednio dużej pojemności. Procedura w BIOS-ie tych modeli sprawdza podczas uruchamiania, czy używany dysk ma firmware zatwierdzony przez IBM. Jeśli takiego firmware'u nie znajdzie, BIOS w zależności od ustawień sygnalizuje to dźwiękiem lub całkowicie przerywa uruchamianie. Mimo tego komunikatu o błędzie, słynnego „Error 2010”, ThinkPad działa bez zarzutu. Samo ostrzeżenie dźwiękowe podczas uruchamiania irytuje użytkownika i szybko pojawia się chęć uciszenia notebooka przynajmniej na czas startu. Ten artykuł opisuje możliwe i proste rozwiązanie.

Co jest potrzebne

Skrót do zamykania systemu na pulpicie.
Die Shutdown-Verknüpfung auf dem Desktop.
Po pierwsze narzędzie Nircmd. Bez niego lub podobnych narzędzi nie da się z poziomu wiersza poleceń celowo tylko włączyć albo tylko wyłączyć dźwięku.
Następnie dwa skrypty VBS: jeden kopiuje się do autostartu (automute.vbs) lub linkuje tam (to wariant bardziej przejrzysty).
Drugi (shutdown.vbs) kopiuje się na pulpit lub również tworzy do niego skrót. Teraz użytkownik musi tylko przyzwyczaić się do zamykania komputera za pomocą tego skrótu.
Um die Skripte für alles Benutzer auf dem Rechner arbeiten zu lassen, legt man diese unter All Users ab oder verknüpft sie in diesem Profil. Unter Windows XP sind das die Ordner 
C:\Dokumente und Einstellungen\All Users\Startmenü\Programme\Autostart\

dla pliku automute.vbs oraz

C:\Dokumente und Einstellungen\All Users\Desktop\
für shutdown.vbs.

Skrypty

Te skrypty to Visual Basic Scripts (VBS). Korzystają one z Windows Scripting Host (WSH), który jest już domyślnie obecny w systemie Windows. Pliki można po prostu utworzyć i zapisać w edytorze tekstu. Ważne jest tylko, aby miały rozszerzenie .vbs. W tym celu system operacyjny powinien także wyświetlać znane rozszerzenia plików (zobacz tutaj).

automute.vbs

'********************************************************************
' Logon script with MUTE OFF
'
' Version	: 1.2b (09-07-02)
' author	: buergernb
'
' Dieses Script setzt das Tool NIRCMD im Pfad "C:\automute" voraus.
' NIRCMD: http://www.nirsoft.net/utils/nircmd.html
'
' Einfach diese VBS-Datei in den Autostart kopieren oder verknüpfen.
'********************************************************************
 
 
'Erforderlicher Aufruf für eine Shellumgebung.
'------------------------------------------
Set oShell = CreateObject("WScript.Shell")
 
 
'Schaltet den Ton ein.
'-------------------------------------------------
oShell.Run "C:\automute\nircmd.exe mutesysvolume 0"
 
 
'Trigger, der die Windows Eventschleife "abhört".
'Dabei wartet er auf ein Event vom Typ
'"Win32_PowerManagementEvent".
'-------------------------------------------------
Set colMonitoredEvents = GetObject("winmgmts:")._
ExecNotificationQuery("Select * from Win32_PowerManagementEvent") 
 
 
'Die Schleife zur Verarbeitung dieses Events.
'Gibt Win32_PowerManagementEvent die Zahl 4 zurück, 
'ist der Rechner im Begriff in den Standby- oder 
'Hibernate-Modus zu gehen. Also wird der Sound 
'ausgeschaltet. Gibt es die Zahl 7 zurück, wacht der
'Rechner gerade auf und der Ton wird nach einer best. 
'Wartezeit (hier 8000 Millisekunden) wieder eingeschaltet.  
'---------------------------------------------------
Do
   Set objLatestEvent = colMonitoredEvents.NextEvent
 
   Select Case objLatestEvent.EventType
 
     Case 4
       oShell.Run "C:\automute\nircmd.exe mutesysvolume 1", , false
 
     Case 7
       wscript.sleep 8000
       oShell.Run "C:\automute\nircmd.exe mutesysvolume 0", , false
 
   End Select
Loop

shutdown.vbs

'********************************************************************
' Shutdown script with AUTOMUTE
'
' Version	: 1.2b (09-07-02)
' author	: buergernb
'
' Dieses Script setzt das Tool NIRCMD im Pfad "C:\automute" voraus.
' NIRCMD: http://www.nirsoft.net/utils/nircmd.html
'********************************************************************
  
 
'Erforderlicher Aufruf für eine Shellumgebung.
'------------------------------------------
Set oShell = CreateObject("WScript.Shell")
 
 
'Schaltet den Ton ab.
'-------------------------------------------------
oShell.Run "C:\automute\nircmd.exe mutesysvolume 1"
 
 
'Hier wird das Herunterfahren um 1 s verzögert. Die Zahl 
'hinter dem Schalter "-t" kann ist Wartezeit in Sekunden. Sie 
'kann zwischen 0 und 600 (Sekunden) variieren.
'-------------------------------------------------------------
oShell.Run "%systemroot%\system32\shutdown.exe -s -t 00 -f"

Linki

Strona producenta narzędzia Nircmd

Opis Microsoft Windows Scripting Host (WSH)

Wyświetlanie znanych rozszerzeń plików – artykuł na Netzwelt.de

Pobrano z „http://thinkpad-wiki.org/Beim_Herunterfahren_automatisch_auf_lautlos_stellen”
Think-Wiki